Add an example of dogfooding (fix #121)

flake.nix

@@ -33,6 +33,12 @@
           A minimal flake using flake-parts importing nixpkgs with the unfree option.
         '';
       };
+      dogfood = {
+        path = ./template/dogfood;
+        description = ''
+          A minimal flake using flake-parts creating flake modules to build its own outputs.
+        '';
+      };
     };
     flakeModules = {
       easyOverlay = ./extras/easyOverlay.nix;

template/dogfood/flake.nix

@@ -0,0 +1,21 @@
+{
+  description = "Description for the project";
+
+  inputs = {
+    nixpkgs_23_05.url = "github:NixOS/nixpkgs/nixos-23.05";
+  };
+
+  outputs = { flake-parts, self, nixpkgs, ... }@inputs:
+    flake-parts.lib.mkFlake
+      {
+        inherit inputs;
+        moduleLocation = ./flake.nix;
+      }
+      {
+        imports = [
+          ./modules/anotherFlakeModule.nix
+          ./modules/hello.nix
+          ./modules/dev.nix
+        ];
+      };
+}

template/dogfood/modules/anotherFlakeModule.nix

@@ -0,0 +1,8 @@
+{inputs, ...}: {
+  imports = [
+    inputs.flake-parts.flakeModules.flakeModules
+  ];
+  flake.flakeModules.anotherFlakeModule = {
+    # Define another flake module here
+  };
+}

template/dogfood/modules/dev.nix

@@ -0,0 +1,32 @@
+{flake-parts-lib, lib, inputs, ...}@topLevel:
+rec {
+  imports = [
+    inputs.flake-parts.flakeModules.flakeModules
+
+    # Use file name to dogfood a flake module defined from the current flake to avoid infinite recursion
+    ./hello.nix
+
+    {
+      flake.flakeModules.dev.imports = [
+        # Use attributes to reference the flake module from other flakes
+        topLevel.config.flake.flakeModules.hello
+      ];
+    }
+
+    # Reference `flake.flakeModules.dev` via `rec` instead of `config` to avoid infinite recursion
+    flake.flakeModules.dev
+  ];
+
+  flake.flakeModules.dev = {
+    config.systems = [ "x86_64-linux" "aarch64-darwin" ];
+
+    options.perSystem = flake-parts-lib.mkPerSystemOption ({pkgs, ...}@perSystem: {
+      devShells.default = pkgs.mkShell {
+        buildInputs = [ perSystem.config.packages.hello_22_11 ];
+        shellHook = ''
+          hello
+        '';
+      };
+    });
+  };
+}

template/dogfood/modules/hello.nix

@@ -0,0 +1,16 @@
+{inputs, flake-parts-lib, ...}:
+rec {
+  imports = [
+    inputs.flake-parts.flakeModules.flakeModules
+
+    # Reference `flake.flakeModules.hello` via `rec` instead of `config` to avoid infinite recursion
+    flake.flakeModules.hello
+  ];
+
+  flake.flakeModules.hello = {
+    options.perSystem = flake-parts-lib.mkPerSystemOption ({ system, ... }: {
+      packages.hello_22_11 =
+        inputs.nixpkgs_23_05.legacyPackages.${system}.hello;
+    });
+  };
+}