-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy pathuppaal.lex
189 lines (170 loc) · 8.36 KB
/
uppaal.lex
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
(* $Id$
*
* Copyright (c) 2008 Timothy Bourke (University of NSW and NICTA)
* All rights reserved.
*
* This program is free software; you can redistribute it and/or modify it
* under the terms of the "BSD License" which is distributed with the
* software in the file LICENSE.
*
* This program is distributed in the hope that it will be useful, but
* WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the BSD
* License for more details.
*
* ML-Lex lexer for Uppaal 4.x
*
* Derived from the ML-Yacc Pascal example, and the
* Uppaal Timed Automata Parser Library documentation
* (http://www.cs.auc.dk/~behrmann/utap/syntax.html).
*)
(* Type abbreviations to match signature for ML-Yacc *)
structure Tokens = Tokens
type pos = FilePos.pos
type svalue = Tokens.svalue
type ('a, 'b) token = ('a, 'b) Tokens.token
type lexresult = (svalue, pos) token
type arg = FilePos.state
(* Auxilliaries *)
fun addPos (token, st, pos) = let val p=FilePos.currpos (st, pos)
in token (p,p) end
fun addPos2 (token, st, pos) = token (FilePos.currpos (st, pos),
FilePos.currpos (st, pos + 1))
fun addPos3 (token, st, pos) = token (FilePos.currpos (st, pos),
FilePos.currpos (st, pos + 2))
fun eof (yyarg) = Tokens.EOF (FilePos.zero, FilePos.zero)
(* Handle keywords *)
structure Keyword =
KeywordFn (type token=(svalue, pos) token
type pos=pos
val ident=Tokens.ID
val keywords= [
("after_update",Tokens.AFTER_UPDATE),
("and", Tokens.AND),
("assign", Tokens.ASSIGN),
("before_update",Tokens.BEFORE_UPDATE),
("bool", Tokens.BOOL),
("break", Tokens.BREAK),
("broadcast", Tokens.BROADCAST),
("case", Tokens.CASE),
("chan", Tokens.CHAN),
("clock", Tokens.CLOCK),
("commit", Tokens.COMMIT),
("const", Tokens.CONST),
("continue", Tokens.CONTINUE),
("deadlock", Tokens.DEADLOCK),
("default", Tokens.DEFAULT),
("do", Tokens.DO),
("else", Tokens.ELSE),
("exists", Tokens.EXISTS),
("false", Tokens.FALSE),
("for", Tokens.FOR),
("forall", Tokens.FORALL),
("guard", Tokens.GUARD),
("if", Tokens.IF),
("imply", Tokens.IMPLY),
("init", Tokens.INIT),
("int", Tokens.INT),
("meta", Tokens.META),
("not", Tokens.NOT),
("or", Tokens.OR),
("priority", Tokens.PRIORITY),
("process", Tokens.PROCESS),
("progress", Tokens.PROGRESS),
("rate", Tokens.RATE),
("return", Tokens.RETURN),
("scalar", Tokens.SCALAR),
("select", Tokens.SELECT),
("state", Tokens.STATE),
("struct", Tokens.STRUCT),
("switch", Tokens.SWITCH),
("sync", Tokens.SYNC),
("system", Tokens.SYSTEM),
("trans", Tokens.TRANS),
("true", Tokens.TRUE),
("typedef", Tokens.TYPEDEF),
("urgent", Tokens.URGENT),
("void", Tokens.VOID),
("while", Tokens.WHILE)
])
(* NB: FXP gives tabs as "\t" and newlines as "\n". *)
%%
%header (functor UppaalLexFun(structure Tokens : Uppaal_TOKENS
structure FilePos : FILE_POS));
%arg (posstate);
%s COMMENT MCOMMENT;
alpha=[A-Za-z];
digit=[0-9];
underscore=[_];
ws=([\ \t] | "\\t");
newline=(\n | "\\n");
%%
<INITIAL>{ws}+ => (continue());
<INITIAL>{newline} => (FilePos.nextline (yyarg, yypos + 1); continue());
<INITIAL>{alpha}({alpha}|{digit}|{underscore})*
=> (Keyword.keyword (yytext,
FilePos.currpos (yyarg, yypos),
FilePos.currpos (yyarg,
yypos + String.size yytext - 1)));
<INITIAL>{digit}+ => (Tokens.INTEGER (valOf (Int.fromString yytext),
FilePos.currpos (yyarg, yypos),
FilePos.currpos (yyarg,
yypos + String.size yytext - 1)));
<INITIAL>"//" => (YYBEGIN COMMENT; continue());
<INITIAL>"/*" => (YYBEGIN MCOMMENT; continue());
<INITIAL>"(" => (addPos (Tokens.LPAR ,yyarg,yypos));
<INITIAL>")" => (addPos (Tokens.RPAR ,yyarg,yypos));
<INITIAL>"[" => (addPos (Tokens.LSQPAR ,yyarg,yypos));
<INITIAL>"]" => (addPos (Tokens.RSQPAR ,yyarg,yypos));
<INITIAL>"{" => (addPos (Tokens.LBRACE ,yyarg,yypos));
<INITIAL>"}" => (addPos (Tokens.RBRACE ,yyarg,yypos));
<INITIAL>"?" => (addPos (Tokens.QUESTION ,yyarg,yypos));
<INITIAL>":" => (addPos (Tokens.COLON ,yyarg,yypos));
<INITIAL>";" => (addPos (Tokens.SEMICOLON ,yyarg,yypos));
<INITIAL>"." => (addPos (Tokens.DOT ,yyarg,yypos));
<INITIAL>"," => (addPos (Tokens.COMMA ,yyarg,yypos));
<INITIAL>"++" => (addPos2 (Tokens.PLUSPLUS ,yyarg,yypos));
<INITIAL>"--" => (addPos2 (Tokens.MINUSMINUS ,yyarg,yypos));
<INITIAL>"+" => (addPos (Tokens.PLUS ,yyarg,yypos));
<INITIAL>"-" => (addPos (Tokens.MINUS ,yyarg,yypos));
<INITIAL>"!" => (addPos (Tokens.EXCLAM ,yyarg,yypos));
<INITIAL>"*" => (addPos (Tokens.TIMES ,yyarg,yypos));
<INITIAL>"/" => (addPos (Tokens.DIVIDE ,yyarg,yypos));
<INITIAL>"%" => (addPos (Tokens.MOD ,yyarg,yypos));
<INITIAL>"&" => (addPos (Tokens.AMPERSAND ,yyarg,yypos));
<INITIAL>"|" => (addPos (Tokens.BITOR ,yyarg,yypos));
<INITIAL>"^" => (addPos (Tokens.BITXOR ,yyarg,yypos));
<INITIAL>"<<" => (addPos2 (Tokens.SHLEFT ,yyarg,yypos));
<INITIAL>">>" => (addPos2 (Tokens.SHRIGHT ,yyarg,yypos));
<INITIAL>"<" => (addPos (Tokens.LT ,yyarg,yypos));
<INITIAL>"<=" => (addPos2 (Tokens.LE ,yyarg,yypos));
<INITIAL>"==" => (addPos2 (Tokens.EQ ,yyarg,yypos));
<INITIAL>"!=" => (addPos2 (Tokens.NEQ ,yyarg,yypos));
<INITIAL>">=" => (addPos2 (Tokens.GE ,yyarg,yypos));
<INITIAL>">" => (addPos (Tokens.GT ,yyarg,yypos));
<INITIAL>"<?" => (addPos2 (Tokens.MIN ,yyarg,yypos));
<INITIAL>">?" => (addPos2 (Tokens.MAX ,yyarg,yypos));
<INITIAL>"&&" => (addPos2 (Tokens.DBLAMPERSAND ,yyarg,yypos));
<INITIAL>"||" => (addPos2 (Tokens.DBLPIPE ,yyarg,yypos));
<INITIAL>"=" => (addPos (Tokens.ASSIGNMENT ,yyarg,yypos));
<INITIAL>":=" => (addPos2 (Tokens.ASSIGNMENT ,yyarg,yypos));
<INITIAL>"+=" => (addPos2 (Tokens.PLUSASSIGN ,yyarg,yypos));
<INITIAL>"-=" => (addPos2 (Tokens.MINUSASSIGN ,yyarg,yypos));
<INITIAL>"*=" => (addPos2 (Tokens.TIMESASSIGN ,yyarg,yypos));
<INITIAL>"/=" => (addPos2 (Tokens.DIVIDEASSIGN ,yyarg,yypos));
<INITIAL>"%=" => (addPos2 (Tokens.MODASSIGN ,yyarg,yypos));
<INITIAL>"|=" => (addPos2 (Tokens.BITORASSIGN ,yyarg,yypos));
<INITIAL>"&=" => (addPos2 (Tokens.BITANDASSIGN ,yyarg,yypos));
<INITIAL>"^=" => (addPos2 (Tokens.BITXORASSIGN ,yyarg,yypos));
<INITIAL>"<<=" => (addPos3 (Tokens.SHLEFTASSIGN ,yyarg,yypos));
<INITIAL>">>=" => (addPos3 (Tokens.SHRIGHTASSIGN,yyarg,yypos));
<INITIAL>. => (addPos (Tokens.UNKNOWN ,yyarg,yypos));
<COMMENT>{newline} => (FilePos.nextline (yyarg, yypos + 1);
YYBEGIN INITIAL; continue());
<COMMENT>[^\n\\]+ => (continue());
<COMMENT>[\\] => (continue());
<MCOMMENT>{newline} => (FilePos.nextline (yyarg, yypos + 1); continue());
<MCOMMENT>"*/" => (YYBEGIN INITIAL; continue());
<MCOMMENT>"*" => (continue());
<MCOMMENT>[\\] => (continue());
<MCOMMENT>[^*\n\\]+ => (continue());